Paste your text here.{
"page_count":2,
"page_number":1,
"page_size":30,
"total_records":35,
"meetings":[
      {
"uuid":"c7v0ox8sT8+u33386prZjg==",
"id":465763888,
"host_id":"P6vsOBBd333nEC-X58lE7w",
"topic":"PL/SQL Office Hours",
"type":2,
"start_time":"2018-01-19T17:38:11Z",
"duration":30,
"timezone":"America/Chicago",
"created_at":"2018-01-19T17:38:11Z",
"join_url":"https://oracle.zoom.us/j/111222333"
      },
      ...
      {
"uuid":"dn7myRyBTd555t1+2GMsQA==",
"id":389814840,
"host_id":"P6vsOBBd555nEC-X58lE7w",
"topic":"Real Application Clusters Office Hours",
"type":2,
"start_time":"2018-03-28T19:00:00Z",
"duration":60,
"timezone":"UTC",
"created_at":"2018-01-24T16:33:46Z",
"join_url":"https://oracle.zoom.us/j/444555666"
      }
   ]
}

CREATE TABLE dg_zoom_meetings
(
   account_name   VARCHAR2 (100),
   uuid           VARCHAR2 (100),
   id             VARCHAR2 (100),
   host_id        VARCHAR2 (100),
   topic          VARCHAR2 (100),
   TYPE           VARCHAR2 (100),
   start_time     VARCHAR2 (100),
   duration       VARCHAR2 (100),
   timezone       VARCHAR2 (100),
   created_at     VARCHAR2 (100),
   join_url       VARCHAR2 (100),
   created_on     DATE
)
/

INSERT INTO dg_zoom_meetings (account_name,
                              uuid,
                              id,
                              host_id,
                              topic,
                              TYPE,
                              start_time,
                              duration,
                              timezone,
                              created_at,
                              join_url,
                              created_on)
   SELECT account_in,
          uuid,
          id,
          host_id,
          topic,
          TYPE,
          start_time,
          duration,
          timezone,
          created_at,
          join_url,
          SYSDATE
    FROM dual, 
    JSON_TABLE (dg_zoom_mgr.get_meetings(account_in),'$.meetings[*]'
    COLUMNS (
        uuid VARCHAR2 ( 100 ) PATH '$.uuid',
        id VARCHAR2 ( 100 ) PATH '$.id',
        host_id VARCHAR2 ( 100 ) PATH '$.host_id',
        topic VARCHAR2 ( 100 ) PATH '$.topic',
        type VARCHAR2 ( 100 ) PATH '$.type',
        start_time VARCHAR2 ( 100 ) PATH '$.start_time',
        duration VARCHAR2 ( 100 ) PATH '$.duration',
        timezone VARCHAR2 ( 100 ) PATH '$.timezone',
        created_at VARCHAR2 ( 100 ) PATH '$.created_at',
        join_url VARCHAR2 ( 100 ) PATH '$.join_url'
    )
)

ALTER SESSION SET plsql_warnings = 'Error:6009';

CREATE OR REPLACE PACKAGE pkg_test AS
    PROCEDURE test_job (p_test_parameter IN OUT VARCHAR2);
END pkg_test;
/

CREATE OR REPLACE PACKAGE BODY pkg_test AS
    PROCEDURE test_job (p_test_parameter IN OUT VARCHAR2) IS
    BEGIN
      NULL;
    EXCEPTION
        WHEN OTHERS THEN NULL;
    END test_job;
END pkg_test;
/

SQL> ALTER SESSION SET plsql_warnings = 'Error:6009';

Session altered.

SQL> CREATE OR REPLACE PACKAGE pkg_test
  2  AS
  3     PROCEDURE test_job (p_test_parameter IN OUT VARCHAR2);
  4  END pkg_test;
  5  /

Package PKG_TEST compiled

SQL> SHOW ERRORS
No errors.
SQL> CREATE OR REPLACE PACKAGE BODY pkg_test
  2  AS
  3     PROCEDURE test_job (p_test_parameter IN OUT VARCHAR2)
  4     IS
  5     BEGIN
  6        DBMS_OUTPUT.put_line ('abc');
  7     EXCEPTION
  8        WHEN OTHERS
  9        THEN
 10           NULL;
 11     END test_job;
 12  END pkg_test;
 13  /

Package Body PKG_TEST compiled

Errors: check compiler log

SQL> SHOW ERRORS

Errors for PACKAGE BODY QDB_PROD.PKG_TEST:

LINE/COL ERROR
-------- -----------------------------------------------------------------
8/12     PLS-06009: procedure "TEST_JOB" OTHERS handler does not end in RAISE or
         RAISE_APPLICATION_ERROR

Sometimes relatively simple tasks can also be critical tasks, 
in which case simplicity becomes a significant advantage (a feature, not a bug).

• Server side condition, whether PL/SQL code or client-side JavaScript (as in, "Item = Value')
• "When Button Pressed" set
• Authorization scheme

SELECT page_id, process_name
    FROM apex_application_page_proc
   WHERE COALESCE (condition_type, 
                   when_button_pressed, 
                   authorization_scheme)
         IS NULL
ORDER BY page_id

Hopefully you can find that useful as well. But what I wanted to focus on in this post is: how did I know the names of columns to reference in the query?

You could try to find descriptions in doc, but an even better way to get your answer is from within APEX Application Builder itself.

Click on Workspace Utilities:

Then Application Express Views:

Then use the handy interactive report to find your view:












Then either build and save a report right inside Application Builder or find the columns of interest and roll your own, as I did:

DECLARE
   TYPE numbers_t IS TABLE OF NUMBER;
   l_numbers numbers_t := numbers_t (1, 2, 3);
BEGIN
   DBMS_OUTPUT.put_line (l_numbers.COUNT);
END;

DECLARE
   TYPE numbers_t IS TABLE OF NUMBER INDEX BY PLS_INTEGER;
   l_numbers numbers_t;
BEGIN
   l_numbers (1) := 100;
   l_numbers (2) := 1000;
   l_numbers (3) := 10000;
END;

DECLARE
   TYPE person_rt IS RECORD (last_name VARCHAR2(100), hair_color VARCHAR2(100));
   l_person person_rt;
BEGIN
   l_person.last_name := 'Feuerstein';
   l_person.hair_color := 'Not Applicable';
END;

DECLARE 
   TYPE species_rt IS RECORD ( 
      species_name           VARCHAR2 (100), 
      habitat_type           VARCHAR2 (100), 
      surviving_population   INTEGER); 

   l_elephant   species_rt := species_rt ('Elephant', 'Savannah', '10000'); 

   PROCEDURE display_species ( 
      species_in species_rt DEFAULT species_rt ('Not Set', 'Global', 0)) 
   IS 
   BEGIN 
      DBMS_OUTPUT.put_line ('Species: ' || species_in.species_name); 
      DBMS_OUTPUT.put_line ('Habitat: ' || species_in.habitat_type); 
      DBMS_OUTPUT.put_line ('# Left: '  || species_in.surviving_population); 
   END; 
BEGIN 
   display_species (l_elephant); 

   /* Use the default */ 
   display_species (); 
END;
/

Species: Elephant
Habitat: Savannah
# Left: 10000
Species: Not Set
Habitat: Global
# Left: 0

DECLARE 
   TYPE species_rt IS RECORD ( 
      species_name           VARCHAR2 (100), 
      habitat_type           VARCHAR2 (100), 
      surviving_population   INTEGER); 

   l_elephant   species_rt 
      := species_rt (species_name           => 'Elephant', 
                     surviving_population   => '10000', 
                     habitat_type           => 'Savannah'); 
BEGIN 
   DBMS_OUTPUT.put_line ('Species: ' || l_elephant.species_name); 
END;
/

Species: Elephant

DECLARE 
   TYPE ints_t IS TABLE OF INTEGER 
      INDEX BY PLS_INTEGER; 

   l_ints   ints_t := ints_t (1 => 55, 2 => 555, 3 => 5555); 
BEGIN 
   FOR indx IN 1 .. l_ints.COUNT 
   LOOP 
      DBMS_OUTPUT.put_line (l_ints (indx)); 
   END LOOP; 
END;
/

55
555
5555

DECLARE
   TYPE ints_t IS TABLE OF INTEGER
      INDEX BY PLS_INTEGER;

   l_ints   ints_t := ints_t (600 => 55, -5 => 555, 200000 => 5555);
   l_index pls_integer := l_ints.first;
BEGIN
   WHILE l_index IS NOT NULL
   LOOP
      DBMS_OUTPUT.put_line (l_index || ' => ' || l_ints (l_index));
      l_index := l_ints.NEXT (l_index);
   END LOOP;
END;
/

-5 => 555
600 => 55
200000 => 5555

DECLARE 
   TYPE by_string_t IS TABLE OF INTEGER 
      INDEX BY VARCHAR2(100); 

   l_stuff   by_string_t := by_string_t ('Steven' => 55, 'Loey' => 555, 'Juna' => 5555); 
   l_index varchar2(100) := l_stuff.first; 
BEGIN 
   DBMS_OUTPUT.put_line (l_stuff.count); 

   WHILE l_index IS NOT NULL 
   LOOP 
      DBMS_OUTPUT.put_line (l_index || ' => ' || l_stuff (l_index)); 
      l_index := l_stuff.NEXT (l_index); 
   END LOOP; 
END;
/

3
Juna => 5555
Loey => 555
Steven => 55

DECLARE
   TYPE by_string_t IS TABLE OF INTEGER
      INDEX BY VARCHAR2 (100);

   l_stuff   by_string_t := 
      by_string_t (UPPER ('Grandpa Steven') => 55, 
'Loey'||'Juna' => 555, 
                   SUBSTR ('Happy Family', 7) => 5555);

   l_index varchar2(100) := l_stuff.first;
BEGIN
   DBMS_OUTPUT.put_line (l_stuff.count);

   WHILE l_index IS NOT NULL
   LOOP
      DBMS_OUTPUT.put_line (l_index || ' => ' || l_stuff (l_index));
      l_index := l_stuff.NEXT (l_index);
   END LOOP;
END;
/

3
Family => 5555
GRANDPA STEVEN => 55
LoeyJuna => 555

DECLARE
   TYPE species_rt IS RECORD (
      species_name VARCHAR2 (100),
      habitat_type VARCHAR2 (100),
      surviving_population INTEGER
   );

   TYPE species_t IS TABLE OF species_rt INDEX BY PLS_INTEGER;

   l_species   species_t := 
      species_t (
         2 => species_rt ('Elephant', 'Savannah', '10000'), 
         1 => species_rt ('Dodos', 'Mauritius', '0'), 
         3 => species_rt ('Venus Flytrap', 'North Carolina', '250'));
BEGIN
   FOR indx IN 1 .. l_species.COUNT
   LOOP
      DBMS_OUTPUT.put_line (l_species (indx).species_name);
   END LOOP;
END;
/

Dodos
Elephant
Venus Flytrap

Championship Performance History

1. PL/SQL will now be a case-insensitive language. Sort of.
2. Only lower-case letters will be supported.
3. All keywords will now be encased within squiggly brackets. 
4. The name of the language will change to {plsql}. 
5. SQL statements are replaced by “yo, oracle!” commands.
6. All procedures and functions are implemented as recursive callback functions executed asynchronously across all Oracle Database instances in all parallel universes available through the Oracle Quantum Universe Cloud Service.

BEGIN
   DBMS_OUTPUT.PUT_LINE (‘Hello World’);
EXCEPTION 
   WHEN OTHERS 
   THEN
      NULL;
END;
/

{begin}
    {'Hello {dbms_output(.)put_line} World’)(call)(home)(et);
    {wotn};
{end};
/

DECLARE
   l_dummy sys.dual.dummy%TYPE;
BEGIN
   SELECT dummy
     INTO l_dummy
     FROM sys.dual;
END;
/

{declare}
   l_dummy {yooracle}”What’s the type of dummy in dual?”;
{begin}
   {yooracle}”What’s the value of dummy in dual?”:l_dummy;
{end};
/

{begin}
   {ihaveadream}”What’s the running total for all orders placed 
                last month by customers located within a kilometer 
                of their parents?”
   => {oraclevrconsole};
{end};
/

If I have a procedure that is AUTONOMOUS_TRANSACTION that does an insert and then it calls a procedure with an insert, does the second procedure need a commit, or will the procedure with the AUTONOMOUS_TRANSACTION handle the commit? If you don't know off the top of your head, don't worry, I can build a test.

PRAGMA AUTONOMOUS_TRANSACTION;

Before the subprogram can be closed and control passed back to the calling block, any DML changes made within that subprogram must be committed or rolled back.

CREATE OR REPLACE FUNCTION nothing RETURN INTEGER
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   UPDATE employees SET last_name = 'abc';

   RETURN 1;
END;
/

BEGIN
   DBMS_OUTPUT.put_line (nothing);
END;
/

ORA-06519: active autonomous transaction detected and rolled back
ORA-06512: at "STEVEN.NOTHING", line 10
ORA-06512: at line 2

CREATE TABLE me_and_my_lovelies (name VARCHAR2 (100));

BEGIN
   INSERT INTO me_and_my_lovelies VALUES ('Grandpa Steven');
   INSERT INTO me_and_my_lovelies VALUES ('Loey');
   INSERT INTO me_and_my_lovelies VALUES ('Juna');
   COMMIT;
END;
/

CREATE OR REPLACE PROCEDURE not_auton_no_commit
   AUTHID DEFINER
IS
BEGIN
   UPDATE me_and_my_lovelies
      SET name = UPPER (name);
END not_auton_no_commit;
/

CREATE OR REPLACE PROCEDURE auton_commit
   AUTHID DEFINER
IS
   PRAGMA AUTONOMOUS_TRANSACTION;
BEGIN
   not_auton_no_commit ();

   COMMIT;
END auton_commit;
/

BEGIN
   auton_commit;
END;
/

SELECT COUNT(*) low_name
  FROM me_and_my_lovelies
 WHERE name <> UPPER (name)
/

LOW_NAME
--------
0

Before the subprogram can be closed and control passed back to the calling block, any DML changes made within that subprogram must be committed or rolled back.

• Orange theme: all that red was hurting our eyes, but the main reason to switch to orange was to make it visually clear that this site, as with AskTOM, is part of the broader Oracle Developer initiative.
• Site search: type in a keyword, such as "FORALL" or "listagg" in the search bar on the home page, and we will find all quizzes, workouts and classes that match your criteria. You can further hone your search on the results page.
• The tournament quizzes are now offered on the home page; no need to click on the Tournaments tab to see them. These quizzes are produced fresh each week, and often focus on the latest features in SQL, PL/SQL and Oracle Database.
• Your recent activity on the site is available on the home page so that you can more easily continue your workout or class, or check the results of a recently-completed quiz.
• Improved performance on the Tournament Archive (formerly Library) page, the Quizzes Taken page and more.
• Redesigned workouts and classes page to make it easier to find and take these exercises at the gym.

• The Trivadis class (which consisted of a single workout) is now a workout. All classes on the Dev Gym henceforth will consist of multiple modules. If you were in the middle of taking that class, visit the Workouts page to continue via the workout.

Don't forget the table alias.

CREATE TYPE food_t AS OBJECT (
   NAME         VARCHAR2 (100)
 , food_group   VARCHAR2 (100)
 , grown_in     VARCHAR2 (100)
)
/

CREATE TABLE food_table (id number primary key, my_food food_t)
/

BEGIN
   INSERT INTO food_table
        VALUES (1, NEW food_t ('Mutter Paneer', 'Curry', 'India'));

   INSERT INTO food_table
        VALUES (2, NEW food_t ('Cantaloupe', 'Fruit', 'Backyard'));

   COMMIT;
END;
/

SQL> SELECT * FROM food_table;

        ID
   ID MY_FOOD(NAME, FOOD_GROUP, GROWN_IN)                                             
----- ------------------------------------------
    1 FOOD_T('Mutter Paneer', 'Curry', 'India')                                       
    2 FOOD_T('Cantaloupe', 'Fruit', 'Backyard') 

SQL> SELECT name FROM food_table;

Error starting at line : 1 in command -
SELECT name FROM food_table
Error at Command Line : 1 Column : 8
Error report -
SQL Error: ORA-00904: "NAME": invalid identifier

SQL> SELECT my_food.name FROM food_table;
Error starting at line : 1 in command -
SELECT my_food.name FROM food_table
Error at Command Line : 1 Column : 8
Error report -
SQL Error: ORA-00904: "MY_FOOD"."NAME": invalid identifier

SQL> SELECT ft.my_food.name FROM food_table ft;

MY_FOOD.NAME                                                                    
-----------------------------------------------
Mutter Paneer                                                                   
Cantaloupe                                                                      

SQL> SELECT ft.my_food.name FROM food_table ft
  2   WHERE ft.my_food.name LIKE 'C%';

MY_FOOD.NAME                                                                    
-----------------------------------------------
Cantaloupe         

• FORMAT_CALL_STACK - answering the question "How did I get here?"
• FORMAT_ERROR_STACK - answering the question "What was the error?" (or a stack of errors, depending on the situation)
• FORMAT_ERROR_BACKTRACE - answering the question "On what line was my error raised?"

CREATE OR REPLACE PROCEDURE p3
   AUTHID DEFINER
IS
BEGIN
   p2;
EXCEPTION
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.put_line (DBMS_UTILITY.format_error_stack);
      DBMS_OUTPUT.put_line (DBMS_UTILITY.format_error_backtrace);
      RAISE;
END;

ORA-06501: PL/SQL: program error

ORA-06512: at "STEVEN.P1", line 4
ORA-06512: at "STEVEN.PKG", line 6
ORA-06512: at "STEVEN.P2", line 5
ORA-06512: at "STEVEN.P3", line 5

ORA-06501: PL/SQL: program error
ORA-06512: at "STEVEN.P1", line 4
ORA-06512: at "STEVEN.PKG", line 6
ORA-06512: at "STEVEN.P2", line 5

ORA-06512: at "STEVEN.P1", line 4
ORA-06512: at "STEVEN.PKG", line 6
ORA-06512: at "STEVEN.P2", line 5
ORA-06512: at "STEVEN.P3", line 5

A BEFORE INSERT trigger will not cause a mutating table error as long as the triggering INSERT statement is a single row insert (INSERT-VALUES).

CREATE TABLE qz_flowers
(
   fl_num    NUMBER,
   fl_name   VARCHAR2 (30)
)
/

CREATE OR REPLACE TRIGGER qz_flowers_bir
   BEFORE INSERT ON qz_flowers
   FOR EACH ROW
DECLARE
   l_count INTEGER;
BEGIN
   SELECT COUNT (*) INTO l_count FROM qz_flowers;
   DBMS_OUTPUT.PUT_LINE ('Count = ' || l_count);
END;
/

SQL> BEGIN
  2     INSERT INTO qz_flowers VALUES (100, 'Orchid');
  3     DBMS_OUTPUT.PUT_LINE ('Inserted');
  4  END;
  5* /

Count = 0
Inserted

SQL> BEGIN
  2     INSERT INTO qz_flowers VALUES (100, 'Orchid');
  3     INSERT INTO qz_flowers VALUES (200, 'Tulip');
  4     DBMS_OUTPUT.PUT_LINE ('Inserted');
  5  END;
  6  /
Count = 0
Count = 1
Inserted

SQL> BEGIN
  2     INSERT INTO qz_flowers 
  3        SELECT 100, 'Orchid' FROM DUAL 
  4        UNION ALL
  5        SELECT 200, 'Tulip' FROM DUAL;
  6     DBMS_OUTPUT.PUT_LINE ('Inserted');
  7  END;
  8  /

Error starting at line : 1 in command -
BEGIN
   INSERT INTO qz_flowers 
      SELECT 100, 'Orchid' FROM DUAL 
      UNION ALL
      SELECT 200, 'Tulip' FROM DUAL;
   DBMS_OUTPUT.PUT_LINE ('Inserted');
END;
Error report -
ORA-04091: table QDB_PROD.QZ_FLOWERS is mutating, trigger/function may not see it
ORA-06512: at "QDB_PROD.QZ_FLOWERS_BIR", line 4
ORA-04088: error during execution of trigger 'QDB_PROD.QZ_FLOWERS_BIR'
ORA-06512: at line 2
04091. 00000 -  "table %s.%s is mutating, trigger/function may not see it"
*Cause:    A trigger (or a user defined plsql function that is referenced in
           this statement) attempted to look at (or modify) a table that was
           in the middle of being modified by the statement which fired it.
*Action:   Rewrite the trigger (or function) so it does not read that table.

SQL> BEGIN
  2     INSERT INTO qz_flowers 
  3        SELECT 100, 'Orchid' FROM DUAL;
  4     DBMS_OUTPUT.PUT_LINE ('Inserted');
  5  END;
  6  /

Error report -
ORA-04091: table QDB_PROD.QZ_FLOWERS is mutating, trigger/function may not see it

SQL> DECLARE
  2     TYPE flowers_t IS TABLE OF qz_flowers%ROWTYPE;
  3     l_flowers flowers_t := flowers_t();
  4  BEGIN
  5     l_flowers.EXTEND;
  6     l_flowers (1).fl_num := 100;
  7     l_flowers (1).fl_name := 'Orchid';
  8  
  9     FORALL indx IN 1 .. l_flowers.COUNT
 10        INSERT INTO qz_flowers VALUES l_flowers (indx);
 11     DBMS_OUTPUT.PUT_LINE ('Inserted');
 12  END;
 13  /
Count = 0
Inserted

SQL> DECLARE
  2     TYPE flowers_t IS TABLE OF qz_flowers%ROWTYPE;
  3     l_flowers flowers_t := flowers_t();
  4  BEGIN
  5     l_flowers.EXTEND (2);
  6     l_flowers (1).fl_num := 100;
  7     l_flowers (1).fl_name := 'Orchid';
  8     l_flowers (2).fl_num := 200;
  9     l_flowers (2).fl_name := 'Tulip';
 10  
 11     FORALL indx IN 1 .. l_flowers.COUNT
 12        INSERT INTO qz_flowers VALUES l_flowers (indx);
 13     DBMS_OUTPUT.PUT_LINE ('Inserted');
 14  END;
 15  /
Count = 0

Error report -
ORA-04091: table QDB_PROD.QZ_FLOWERS is mutating, trigger/function may not see it

The table function will be called for each row in the table/view that is providing the column to the function. 

CREATE TABLE things
(
   thing_id     NUMBER,
   thing_name   VARCHAR2 (100)
)
/

BEGIN
   INSERT INTO things VALUES (1, 'Thing 1');
   INSERT INTO things VALUES (2, 'Thing 2');
   COMMIT;
END;
/

CREATE OR REPLACE TYPE numbers_t IS TABLE OF NUMBER
/

CREATE OR REPLACE FUNCTION more_numbers (id_in IN NUMBER)
   RETURN numbers_t
IS
   l_numbers   numbers_t := numbers_t ();
BEGIN
   l_numbers.EXTEND (id_in * 5);

   FOR indx IN 1 .. id_in * 5
   LOOP
      l_numbers (indx) := indx;
   END LOOP;

   DBMS_OUTPUT.put_line ('more numbers');
   RETURN l_numbers;
END;
/

BEGIN
   FOR rec IN (SELECT th.thing_name, t.COLUMN_VALUE thing_number
                 FROM things th, TABLE (more_numbers (th.thing_id)) t)
   LOOP
      DBMS_OUTPUT.put_line ('more numbers ' || rec.thing_number);
   END LOOP;
END;
/

more numbers
more numbers
more numbers 1
more numbers 2
more numbers 3
more numbers 4
more numbers 5
more numbers 1
more numbers 2
more numbers 3
more numbers 4
more numbers 5
more numbers 6
more numbers 7
more numbers 8
more numbers 9
more numbers 10

CREATE OR REPLACE FUNCTION more_numbers (id_in IN NUMBER)
   RETURN numbers_t PIPELINED
IS
BEGIN
   DBMS_OUTPUT.put_line ('more numbers');
   FOR indx IN 1 .. id_in * 5
   LOOP
      PIPE ROW (indx);
   END LOOP;
   RETURN;
END;
/

BEGIN
   FOR rec IN (SELECT th.thing_name, t.COLUMN_VALUE thing_number
                 FROM things th, TABLE (more_numbers (th.thing_id)) t)
   LOOP
      DBMS_OUTPUT.put_line ('more numbers ' || rec.thing_number);
   END LOOP;
END;
/

more numbers
more numbers
more numbers 1
more numbers 2
more numbers 3
more numbers 4
more numbers 5
more numbers 1
more numbers 2
more numbers 3
more numbers 4
more numbers 5
more numbers 6
more numbers 7
more numbers 8
more numbers 9
more numbers 10

• Results of the quiz you just completed
• Confirmation of sign-up in a class
• Reminder to take our weekly tournament quizzes
• Hourly reports to site admins with any new errors in our log
• Weekly activity summaries to quizmasters

When running in development or test, our users should never get an email. Specifically, unless the email "send to" is one of our developers, redirect all emails to the admin email address.

Never call APEX_MAIL.SEND directly. Instead call qdb_communication_mgr.send_email. 

PROCEDURE send_mail (
   to_user_id_in      IN INTEGER,
   subject_in         IN VARCHAR2,
   html_in            IN CLOB,
   push_to_queue_in   IN BOOLEAN DEFAULT TRUE)
IS
   l_email_id   INTEGER;
   l_text       CLOB;

   /* Just a placeholder for this demonstration */ 
   FUNCTION is_developer (user_id_in IN INTEGER)
      RETURN BOOLEAN
   IS
   BEGIN
      RETURN TRUE;
   END;

   FUNCTION user_email_address (user_id_in IN INTEGER)
      RETURN VARCHAR2
   IS
      l_email_address   qdb_users.email_address%TYPE;
   BEGIN
      SELECT email_address
        INTO l_email_address
        FROM qdb_users
       WHERE user_id = user_id_in;

      RETURN l_email_address;
   END;

   FUNCTION send_to_email_address (user_id_in IN INTEGER)
      RETURN VARCHAR2
   IS
      c_email_address   qdb_users.email_address%TYPE
                           := user_email_address (user_id_in);
   BEGIN
      RETURN CASE
                WHEN qdb_utilities.in_production THEN c_email_address
                WHEN is_developer (user_id_in) THEN c_email_address
                ELSE qdb_config.admin_email_address ()
             END;
   END;
BEGIN
   l_email_id :=
      apex_mail.send (p_to          => send_to_email_address (to_user_id_in),
                      p_from        => 'noreply@oracle.com',
                      p_subj        => subject_in,
                      p_body        => l_text,
                      p_body_html   => html_in,
                      p_cc          => NULL,
                      p_bcc         => NULL);

   IF push_to_queue_in
   THEN
      apex_mail.push_queue;
   END IF;
END send_mail;

• I create a nested function to return the email address to which the email will be sent. Inside that function, I have all the logic to implement my requirement.
• The qdb_utilities package contains a function that returns TRUE if I am currently running this code in production.
• Since the only call to apex_mail.send occurs within my send_mail procedure, I am now 100% protected from accidentally sending out an email to users when it was not intended.
• I don't always push the email out of the queue. For example, when I doing a batch email, I want to wait till everything is put on the queue, and then push it. If I am notifying a user of a specific event or accomplishment, I might want to push immediately.

PROCEDURE send_mail (
   to_user_id_in      IN INTEGER,
   subject_in         IN VARCHAR2,
   html_in            IN CLOB,
   push_to_queue_in   IN BOOLEAN DEFAULT TRUE)
IS
...
BEGIN
   write_to_queue (
     email_sent     => 'N',
     to_address     => send_to_email_address (to_user_id_in),
     from_address   => 'noreply@oracle.com',
     subject        => subject_in,
     body           => l_text,
     body_html      => html_in,
     cc             => NULL,
     bcc            => NULL,
     email_id_out   => l_email_queue_id);

   l_email_id :=
      apex_mail.send (p_to          => send_to_email_address (to_user_id_in),
                      p_from        => 'noreply@oracle.com',
                      p_subj        => subject_in,
                      p_body        => l_text,
                      p_body_html   => html_in,
                      p_cc          => NULL,
                      p_bcc         => NULL);

   IF push_to_queue_in
   THEN
      apex_mail.push_queue;
   END IF;

   mark_email_sent (l_email_queue_id);
END send_mail;

PL/Scope is a compiler-driven tool that collects PL/SQL and SQL identifiers as well as SQL statements usage in PL/SQL source code.  PL/Scope collects PL/SQL identifiers, SQL identifiers, and SQL statements metadata at program-unit compilation time and makes it available in static data dictionary views. The collected data includes information about identifier types, usages (DECLARATION, DEFINITION, REFERENCE, CALL, ASSIGNMENT) and the location of each usage in the source code.

Starting with Oracle Database 12cRelease 2 (12.2), PL/Scope has been enhanced to report on the occurrences of static SQL, and dynamic SQL call sites in PL/SQL units. The call site of the native dynamic SQL (EXECUTE IMMEDIATE, OPEN CURSOR FOR) and DBMS_SQL calls are collected. Dynamic SQL statements are generated at execution time, so only the call sites can be collected at compilation time. The collected data in the new DBA_STATEMENTS view can be queried along with the other data dictionary views to help answer questions about the scope of changes required for programming projects, and performing code analysis. It is also useful to identify the source of SQL statement not performing well.

PL/Scope provides insight into dependencies between tables, views and the PL/SQL units. This level of details can be used as a migration assessment tool to determine the extent of changes required.

PL/Scope can help you answer questions such as :

• Where and how a column x in table y is used in the PL/SQL code?
• Where does the same SQL statement appear more than once in my code
• What are the constants, variables and exceptions in my application that are declared but never used? 
• Is my code at risk for SQL injection?
• What are the SQL statements with an optimizer hint coded in the application? 
• Where is a variable modified in my package? 

1. The compiler, which collects information when compiling source code (e.g. plscope_settings=’identifiers:all’)
2. The dictionary views, providing information about collected identifiers (dba_identifiers) and SQL statements (dba_statements).

• High performance querying with BULK COLLECT
• Super-fast, bulk non-query DML operations with FORALL
• Table functions (functions that can be treated like a table in a SELECT's FROM clause)

The PL/SQL User Guide offers detailed coverage of collection features here. It starts by reviewing the differences between collections types.

An 11-video Youtube playlist on my Practically Perfect PL/SQL channel. Just to give you a sense of the depth of coverage, total time is over 4.5 hours.

Playlist by Manish Sharma: PL/SQL Collections in Oracle Database

Manish (aka, Rebellion Rider) is one of the most prolific publishers of videos on Oracle PL/SQL. Check out this 17 video playlist for fast, basic videos on various aspects of collections.

DECLARE
   l_number NUMBER := NULL;
BEGIN
   ...
END;

DECLARE
   l_number NUMBER;
BEGIN
   ...
END;

DECLARE
   l_now DATE;
BEGIN
   SELECT SYSDATE INTO l_now FROM dual;
END;

DECLARE
   l_next_pky INTEGER;
BEGIN
   SELECT my_seq.NEXTVAL INTO l_next_pky FROM dual;
END;

DECLARE
   l_now DATE;
   l_next_pky INTEGER;
BEGIN
   l_now := SYSDATE;
   l_next_pky := my_seq.NEXTVAL;
END;

DECLARE
   indx   INTEGER;
BEGIN
   FOR indx IN 1 .. 12
   LOOP
      DBMS_OUTPUT.put_line (TO_DATE ('2018-' || indx || '-01', 'YYYY-MM-DD'));
   END LOOP;

   IF indx = 12
   THEN
      DBMS_OUTPUT.put_line ('Displayed all twelve months!');
   END IF;
END;
/

DECLARE
   rec   employees%ROWTYPE;
BEGIN
   FOR rec IN (SELECT * FROM employees)
   LOOP
      DBMS_OUTPUT.put_line (rec.last_name);
   END LOOP;

   IF rec.employee_id IS NOT NULL
   THEN
      DBMS_OUTPUT.put_line ('Displayed all employees!');
   END IF;
END;
/

BEGIN
   FOR indx IN 1 .. 12
   LOOP
      DBMS_OUTPUT.put_line (TO_DATE ('2018-' || indx || '-01', 'YYYY-MM-DD'));
   END LOOP;

   DBMS_OUTPUT.put_line ('Displayed all twelve months!');
END;
/

DECLARE
   l_displayed BOOLEAN := FALSE;
BEGIN
   FOR rec IN (SELECT * FROM employees)
   LOOP
      DBMS_OUTPUT.put_line (rec.last_name);
      l_displayed := TRUE;
   END LOOP;

   IF l_displayed
   THEN
      DBMS_OUTPUT.put_line ('Displayed all employees!');
   END IF;
END;
/

DECLARE
   l_id   employees.employee_id%TYPE;
BEGIN
   SELECT employee_id
     INTO l_id
     FROM employees
    WHERE 1 = 2;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.put_line ('Not with that WHERE clause!');
END;
/

Not with that WHERE clause!

BEGIN
   UPDATE employees
      SET last_name = UPPER (last_name)
    WHERE 1 = 2;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.put_line ('Not with that WHERE clause!');
END;
/

BEGIN
   UPDATE employees
      SET last_name = UPPER (last_name)
    WHERE 1 = 2;

    IF SQL%ROWCOUNT = 0
    THEN
       DBMS_OUTPUT.put_line ('Not with that WHERE clause!');
    END IF;
END;
/

Not with that WHERE clause!

CREATE TABLE parts
(
   partnum    NUMBER PRIMARY KEY,
   partname   VARCHAR2 (15) UNIQUE NOT NULL
)
/

BEGIN
   FOR indx IN 1 .. 10000
   LOOP
      INSERT INTO parts (partnum, partname)
           VALUES (indx, 'Part' || indx);
   END LOOP;
END;
/

BEGIN
   INSERT INTO parts
          SELECT LEVEL, 'Part ' || LEVEL
            FROM DUAL
      CONNECT BY LEVEL <= 1000;
END;

DECLARE
   TYPE parts_t IS TABLE OF parts%ROWTYPE;

   l_parts   parts_t := parts_t ();
BEGIN
   FOR indx IN 1 .. 10000
   LOOP
      l_parts (indx).partnum := indx;
      l_parts (indx).partname := 'Part' || indx;
   END LOOP;

   FORALL indx IN 1 .. l_parts.COUNT
      INSERT INTO parts (partnum, partname)
           VALUES (l_parts (indx).partnum, l_parts (indx).partname);
END;
/